ON ERROR PROCe
DIM ROM% 512*1024
VDU 26,12

REM fill empty locations with &FF
FOR X%=ROM% TO ROM%+512*1024-1
!X%=-1
NEXT

RESTORE +0
REM game directory at 3C00

READ C%
B%=0
E%=0

FOR X=1 TO C%
READ FILENAME$,NAME$,SIZE%
IF B% MOD 8 = 0 THEN PRINT '"Short game needed for thefollowing slot"

PRINT "File ";FILENAME$;" Game ";NAME$;" Blocks needed ";SIZE%
CHUNK=ROM%+B%*&4000
DIR=ROM%+&3C00+16*E%
DIR?0=B%+((SIZE%-1)<<6)
NAME$+=STRING$(14," ")
FOR Z%=1 TO 14
DIR?Z%=ASC(MID$(NAME$,Z%))
NEXT
DIR?15=0
OSCLI "LOAD RUNGAMES."+FILENAME$+" "+STR$~CHUNK
B%+=SIZE%
E%+=1

NEXT

PRINT "Total blocks used ";B%
PRINT "Total games added ";E%

REM NOW DUMP THE ROM 7 CODE TO OFFSET &2000
OSCLI "LOAD !GAMEMTX.ROMS.GAMEROM "+STR$~(ROM%+&2000)

REM and copy to offsets &22000,&42000 &62000
REM cant just *load, as directory info has to be copied too

FOR X%=0 TO &1FFF STEP4
Y%=!(ROM%+&2000+X%)
!(ROM%+&22000+X%)=Y%
!(ROM%+&42000+X%)=Y%
!(ROM%+&62000+X%)=Y%
NEXT

OSCLI "SAVE !GAMEMTX.BIGGAMEROM "+STR$~ROM%+" +80000 0 0"

END

REM Remember to ensure under 8k games in banks 0,8,16 & 24

DATA 22
DATA TOADO,"Toado",1
DATA ALICE,Alice,2
DATA ALPHA,"Mission Alpha",1
DATA ASTROPAC,"Astro Pac",1
DATA BLOBBO,Blobbo,1
DATA CHESS,Chess,2

DATA ARCAZION,Arcazions,1
DATA DRAUGHTS,Draughts,1
DATA HAWKWARS,Hawkwars,1
DATA KNUCKLES,Knuckles,1
DATA NEMO,Nemo,1
DATA S_MINE,"SuperMinefield",1
DATA OBLOIDS,Obloids,1
DATA TURBO,"Turbo",1

DATA OMEGA,"Mission Omega",1
DATA PHAID,Phaid,1
DATA QOGO,Qogo,1
DATA REVERSI,Reversi,1
DATA SCANNER,"SurfaceScanner",2
DATA TACHYON,"TachyonFighter",1
DATA STAR,"Star Command",1

DATA KILOPEAD,Kilopead,1


DEF PROCe
REPORT
PRINT " at line ";ERL
*CLOSE
END